spieleprogrammierer.de - Forum und Wiki zur Spieleprogrammierung und Spieleentwicklung

Quellcode

class InputManager
{
  //Listen der momentan gedrückten Tasten
  private char m_cKeyPressedChars[] = new char[0];
  private int m_cKeyPressedCodes[] = new int[0];
  
  //setKeyPressed()-Methode, fügt den Listen der gedrückten Tasten
  //eine neue Taste hinzu
  public void setKeyPressed(char Char, int Code)
  {
    boolean isActive = false;
    //Falls die Taste schon in den Listen steht, wird kein neuer Eintrag erzeugt
    for(int i = 0; i < m_cKeyPressedChars.length; i++)
    {
      if(m_cKeyPressedCodes[i] == Code)
      {
        isActive = true;
      }
    } 
    if(!isActive)
    {
      m_cKeyPressedChars = (char[]) append(m_cKeyPressedChars, Char);
      m_cKeyPressedCodes = (int[]) append(m_cKeyPressedCodes, Code); 
    }
  }
  
  //setKeyReleased()-Methode, löscht die losgelassene Taste aus den Listen
  public void setKeyReleased(char Char, int Code)
  { 
    //Ist mehr als eine Taste gedrückt, muss vor dem kürzen der Liste das
    //zu löschende Element mit dem letzten Element getauscht werden
    if(m_cKeyPressedCodes.length > 1)
    {
      int i = 0;
      boolean finished = false;
      while(i < m_cKeyPressedCodes.length && finished == false)
      {
        if(m_cKeyPressedCodes[i] == Code)
        {
          int iTmp = m_cKeyPressedCodes[i];
          m_cKeyPressedCodes[i] = m_cKeyPressedCodes[m_cKeyPressedCodes.length-1];
          m_cKeyPressedCodes[m_cKeyPressedCodes.length-1] = iTmp;
          char cTmp = m_cKeyPressedChars[i];
          m_cKeyPressedChars[i] = m_cKeyPressedChars[m_cKeyPressedChars.length-1];
          m_cKeyPressedChars[m_cKeyPressedChars.length-1] = cTmp;
          finished = true;
        } 
        i++;       
      }
    }
    //Liste kürzen
    m_cKeyPressedCodes = (int[]) shorten(m_cKeyPressedCodes);
    m_cKeyPressedChars = (char[]) shorten(m_cKeyPressedChars);
  }
  
  //Rückgabefunktionen, ob eine bestimmte Taste gedrückt wurde
  boolean isKeyPressed(int code)
  {
    for(int i = 0; i < m_cKeyPressedCodes.length; i++)
    {
      if(m_cKeyPressedCodes[i] == code)
      {
        return true;
      }
    }
    return false;
  }
  
  boolean isKeyPressed(char code)
  {
    for(int i = 0; i < m_cKeyPressedChars.length; i++)
    {
      if(m_cKeyPressedChars[i] == code)
      {
        return true;
      }
    }
    return false;
  }
}

InputManager n = new InputManager();

void keyPressed()
{
  n.setKeyPressed(key, keyCode);
}

void keyReleased()
{
  n.setKeyReleased(key, keyCode);
}

void setup()
{
  size(640, 480);
  smooth();
}

void draw()
{
  background(0);
  if(n.isKeyPressed(UP))
  {
    stroke(255, 0, 0);
    fill(0, 0, 0);
    ellipseMode(RADIUS);
    ellipse(160, 240, 50, 50);
  }
  if(n.isKeyPressed(LEFT))
  {
    stroke(0, 255, 0);
    fill(0, 0, 0);
    ellipseMode(RADIUS);
    ellipse(320, 240, 50, 50);
  }
  if(n.isKeyPressed(RIGHT))
  {
    stroke(0, 0, 255);
    fill(0, 0, 0);
    ellipseMode(RADIUS);
    ellipse(480, 240, 50, 50);
  }
}