spieleprogrammierer.de - Forum und Wiki zur Spieleprogrammierung und Spieleentwicklung

Quellcode

@name holoHeliVorlage
@persist [E O HoloMainEnt TargetEnt Projectile]:entity  [HoloMainEntPos AimPos]:vector
@persist H:table 
@persist Switch Flex_VertValue StopMe
@persist Speed UpSpeed MaxSpeed UpMaxSpeed

if(first() | duped()) {
    runOnTick(1)
    runOnLast(1)
    runOnChat(1)
    
    E = entity()
    O = owner()
    
    MaxSpeed = 50
    UpMaxSpeed = 2
    
    HoloMainEnt = holoCreate(1, E:toWorld(vec(0,0,150)))
    holoScaleUnits(1, vec(5,5,5))
    holoModel(1, "models/gunship.mdl")
    holoAnim(1, "prop_turn")
    HoloMainEnt:soundPlay("engine", 0, "/npc/combine_gunship/engine_whine_loop1.wav")
    soundVolume("engine", 1)
    
    function entity:targetEnt(FuncTarget:entity) {
        Idx = holoIndex(This)
        DirectionAng = (FuncTarget:pos() - This:pos()):toAngle()
        SAng = This:angles() 
        SAng += angnorm(DirectionAng - SAng)*0.05
        print(4, ""+SAng:yaw())
        holoAng(Idx, SAng)
    }   
    
    function entity:attackEnt(FuncTarget:entity) {
        if(FuncTarget) {
        #Nachher code mit schiessen
                Distance = This:pos():distance(FuncTarget:pos())
                if(FuncTarget:isPlayer()) {
                    Direction = (FuncTarget:boxCenterW() - This:pos())
                } else {
                    Direction = (FuncTarget:boxCenterW() - This:pos())
                }
                
                DirectionAng = Direction:toAngle()
                Ranger = rangerOffset(Distance-300, This:pos() + vec(0,0,20), Direction)
                if(!Ranger:hit()) {
                    HoloMainEnt:soundPlay("shoot", 0.1, "/weapons/airboat/airboat_gun_energy2.wav") 
                    soundPitch("shoot", 150)
                    Idx = holoIndex(This)
                    holoPos(Idx, This:pos() + -This:right()*3)
                    if(Projectile) {
                        if(clk("shootdelay")) {
                            Rdy = 1
                        }
                    } else {
                        Rdy = 1
                    }
                    if(Rdy) {
                        if(!Projectile) {
                            propSpawnEffect(0)
                            Projectile = propSpawn("models/hunter/plates/plate.mdl", This:pos(), DirectionAng, 0)
                            Projectile:setAlpha(0)
                            Projectile:setMass(10)
                        } else {
                            Projectile:removeTrails()
                            Projectile:setPos(This:pos())
                            Projectile:setAng(DirectionAng)
                            Projectile:setTrails(50,50,0.01,"trails/laser",vec(155,155,0),120)
                        }
                        Projectile:applyForce(Direction*Projectile:mass()*100000)
                    }           
                    timer("shootdelay", 200)
                }
        } else {
            Projectile:propDelete()
        }
        
                
    }
    
    function entity:stopAttack() {
            soundStop("shoot")
    }
    
    function entity:stop() {
        TargetEnt = noentity()
        AimPos = vec()
    }
    
    function entity:rotateGerade() {
        Idx = holoIndex(This)
        SAng = This:angles() 
        SAng += angnorm(This:angles():setPitch(0):setRoll(0) - SAng)*0.05
        holoAng(Idx, SAng)
    }
    
    function number entity:stopAnything() {
        Idx = holoIndex(This)
        Speed -= clamp(Speed, -0.01, 0.01)
        Forward = This:forward()*Speed
        UpSpeed -= clamp(UpSpeed, -0.01, 0.01)
        holoPos(Idx, This:pos() + Forward + vec(0,0,UpSpeed))
        AimPos = vec()
        TargetEnt = noentity()
        if(Speed == 0 & UpSpeed == 0) {
            return 1
        }
        return 0
    }
    
    function number entity:stopMove() {
        Idx = holoIndex(This)
        Speed -= clamp(Speed, -0.1, 0.1)
        Forward = This:forward()*Speed
        UpSpeed -= clamp(UpSpeed, -0.1, 0.1)
        holoPos(Idx, This:pos() + Forward + vec(0,0,UpSpeed))
        if(Speed == 0 & UpSpeed == 0) {
            return 1
        }
        return 0
    }

    function number entity:moveToPos(FuncPos:vector, FuncTopdistance,FuncStopdistance) {
        FuncPos += vec(0,0,FuncTopdistance)
        Distance = This:pos():distance(FuncPos)
        DistanceZ = This:pos():setX(0):setY(0):distance(FuncPos:setX(0):setY(0))
        if(Distance < FuncStopdistance) {
            return 0
        }
        Idx = holoIndex(This)
        Speed = clamp(Speed + 0.1, 0, MaxSpeed)
        TrueSpeed = clamp((Distance+100)/100, 0.01, Speed)
        Forward = This:forward()*clamp((Distance+100)/100, 0.01, Speed)
        if(Speed != TrueSpeed) {
            Speed = TrueSpeed
        }
        Diff = This:pos():z() - FuncPos:z()
        if(Diff > 0) {
            UpSpeed = clamp(UpSpeed - 0.05, -UpMaxSpeed, UpMaxSpeed)
        } elseif(Diff < 0 ) {
            UpSpeed = clamp(UpSpeed + 0.05, -UpMaxSpeed, UpMaxSpeed)
        }
        Up = This:up()*UpSpeed
        holoPos(Idx, This:pos() + Forward + vec(0,0,UpSpeed))
        DirectionVec = (FuncPos) - This:pos()
        DirectionAng = DirectionVec:toAngle()
        SAng = This:angles() 
        SAng += angnorm(DirectionAng - SAng)*clamp(10/Distance,0.01,1)
        holoAng(Idx, SAng)
        return 1
    }
}
if(!Switch) {
    Flex_VertValue += 0.1
    if(Flex_VertValue > 5) {
        Switch = !Switch
    }
} else {
    Flex_VertValue -= 0.1
    if(Flex_VertValue < -5) {
        Switch = !Switch
    }
}
holoSetPose(1, "flex_vert", Flex_VertValue)
AnimationForwardBackVector = HoloMainEnt:forward()*Flex_VertValue/100
AnimationUpDownVector = HoloMainEnt:up()*Flex_VertValue/100
holoPos(1, HoloMainEnt:pos() + AnimationForwardBackVector + -AnimationUpDownVector)

if(changed(HoloMainEnt:pos())) {
    HoloMainEntPos = HoloMainEnt:pos()
    Length = +abs(round($HoloMainEntPos:length(),2))
    soundPitch("engine", 75+Length)
}
#Commands
if(changed(O:keyAttack1()) & O:keyAttack1() & O:weapon():type() == "weapon_crowbar") { HoloMainEnt:stop() 
findIncludeClass("prop*")
findIncludeClass("npc*")
findIncludeClass("player")
findInCone(O:shootPos(), O:eye(), 5000, 10)
TargetEnt = find()
StopMe = 0}
if(changed(O:keyAttack2()) & O:keyAttack2() & O:weapon():type() == "weapon_crowbar") { HoloMainEnt:stop() 
findIncludeClass("prop*")
findIncludeClass("npc*")
findIncludeClass("player")
findInCone(O:shootPos(), O:eye(), 5000, 10)
TargetFollowEnt = find()
if(!TargetEnt) { AimPos = O:aimPos() }
 StopMe = 0}
if(changed(O:keyReload()) & O:keyReload() & O:weapon():type() == "weapon_crowbar") { StopMe = 1 }

if(StopMe == 1) {
    Result = HoloMainEnt:stopAnything()
    if(Result) {
        StopMe = 0
    }
} else {
if(StopMe == 2) {
    Result = HoloMainEnt:stopMove()
    if(Result) {
        StopMe = 0
    }
}
    #Commands execute
    if(TargetEnt) {
        HoloMainEnt:targetEnt(TargetEnt)
        if(!HoloMainEnt:moveToPos(TargetEnt:pos(), 500,1500)) { 
            HoloMainEnt:attackEnt(TargetEnt) 
            StopMe = 2 
        } else { 
            StopMe = 0
        }
    } else {
        if(Projectile) {
            Projectile:propDelete()
        }
    }
    
    if(AimPos) {
        if(!HoloMainEnt:moveToPos(AimPos, 150,100)) { StopMe = 1 }
    }
}
HoloMainEnt:rotateGerade()

E:setText(""+Speed + " " + UpSpeed)

if(chatClk(O)) {

}