spieleprogrammierer.de - Forum und Wiki zur Spieleprogrammierung und Spieleentwicklung

HLSL-Quelltext

VertexOut VS(VertexIn input)
{
    VertexOut output;

    output.posW = mul(float4(input.pos, 1.0f), World).xyz;
    output.normalW = mul(input.normal, (float3x3)WorldInvTranspose);

    output.posH = mul(float4(output.posW, 1.0f), ViewProjection);
    
    output.tex = input.tex;

    output.shadowPos = mul(float4(input.pos, 1.0f), ShadowTransform);

    return output;
}

float4 PS(VertexOut input) : SV_TARGET
{
    input.normalW = normalize(input.normalW);

    float3 toEye = gEyePosW - input.posW;

    // Cache the distance to the eye from this surface point.
    float distToEye = length(toEye);

    // Normalize.
    toEye /= distToEye;

    // Default to multiplicative identity.
    float4 texColor = float4(1, 1, 1, 1);
    texColor = Texture.Sample(Sample, input.tex);

    // Start with a sum of zero. 
    float4 ambient = float4(0.0f, 0.0f, 0.0f, 0.0f);
    float4 diffuse = float4(0.0f, 0.0f, 0.0f, 0.0f);
    float4 spec = float4(0.0f, 0.0f, 0.0f, 0.0f);

    // Sum the light contribution from each light source.  
    ComputeDirectionalLight(material, dirLight, input.normalW, toEye,
        ambient, diffuse, spec);

    float shadow = 1.0f;
    shadow = CalcShadowFactor(SampleShadow, ShadowMap, input.shadowPos);

    diffuse *= shadow;
    spec *= shadow;

    float4 A, D, S;
    [unroll]
    for (int i = 0; i < pointLightCount; i++)
    {
        ComputePointLight(material, pointLight[i], input.posW, input.normalW, toEye, A, D, S);
        ambient += A;
        diffuse += D;
        spec += S;
    }

    // Modulate with late add.
    float4 litColor = texColor*(ambient + diffuse) + spec;

    // Common to take alpha from diffuse material and texture.
    litColor.a = material.Diffuse.a * texColor.a;

    return litColor;
}

HLSL-Quelltext

float CalcShadowFactor(SamplerComparisonState samShadow,
    Texture2D shadowMap,
    float4 shadowPosH)
{
    // Complete projection by doing division by w.
    shadowPosH.xyz /= shadowPosH.w;

    // Depth in NDC space.
    float depth = shadowPosH.z;

    // Texel size.
    const float dx = SMAP_DX;

    float percentLit = 0.0f;
    const float2 offsets[9] =
    {
        float2(-dx,  -dx), float2(0.0f,  -dx), float2(dx,  -dx),
        float2(-dx, 0.0f), float2(0.0f, 0.0f), float2(dx, 0.0f),
        float2(-dx,  +dx), float2(0.0f,  +dx), float2(dx,  +dx)
    };

    [unroll]
    for (int i = 0; i < 9; ++i)
    {
        percentLit += shadowMap.SampleCmpLevelZero(samShadow,
            shadowPosH.xy + offsets[i], depth).r;
    }

    return percentLit /= 9.0f;
}