spieleprogrammierer.de - Forum und Wiki zur Spieleprogrammierung und Spieleentwicklung

HLSL-Quelltext

//////////////////////////////////////////////////////////////////
//Includes
#include"Constants.fx"
#include"Sampler.fx"
#include"Textures.fx"
#include"Lighting.fx"


//////////////////////////////////////////////////////////////////
//Layout
struct VSInput
{
    uint IID                    : SV_InstanceID;
    float3 vPosition            : POSITION0;
    float3 vNormal              : NORMAL0;
    float3 vTangent             : TANGENT0;
    float2 vTextureCoord        : TEXCOORD0;
};

struct PSInput
{
    uint IID                    : INSTANCEID;
    float4 vPosition            : SV_Position;
    float3 vWorldPosition       : POSITION0;
    float3 vNormal              : NORMAL0;
    float3 vTangent             : TANGENT0;
    float3 vBinormal            : BINORMAL0;
    float2 vTextureCoord        : TEXCOORD0;
};

struct PSOutput
{
    float4 Color   : SV_Target0;
};

//VertexShader
PSInput VertexShaderProc(VSInput In)
{
    PSInput Out;
    
    Out.IID= In.IID;
    
    float4 vWorldPosition= mul(float4(In.vPosition, 1.0), Instance[In.IID].mWorld);
    Out.vPosition= mul(vWorldPosition, mViewProjection);
    
    Out.vWorldPosition= vWorldPosition.xyz;
    float3 vNormal= mul(In.vNormal, (float3x3)Instance[In.IID].mWorld);
    Out.vNormal= vNormal;
    
    Out.vTangent= mul(In.vTangent, (float3x3)Instance[In.IID].mWorld);
    Out.vBinormal= cross(Out.vTangent, Out.vNormal);
    
    Out.vTextureCoord= In.vTextureCoord;
    
    return(Out);
}

//PixelShader
PSOutput PixelShaderProc(PSInput In)
{
    PSOutput Out;
    
    //NormalMapping
    column_major float3x3 mTBN= {In.vTangent, In.vBinormal, In.vNormal};
    float3 vNormal= mul(TexNormalHeight.Sample(TextureSamplerWrap, In.vTextureCoord).rgb * 2.0 - 1.0, mTBN);
    
    //Illumination
    float3 SpecularLight= float3(0, 0, 0);
    float3 vViewDir= float3(mView._31, mView._32, mView._33);
    LightSource Light;
    uint LightIndex;

    //Light #0 (Directional)
    LightIndex= Instance[In.IID].aLightIndices[0].LID;
    if(LightIndex != 0xFFFFFFFF)
    {
        Light= aLights[LightIndex];
        SpecularLight+= DirectionalLightSpecular(Light, vNormal, MatSpecularColorPower.a, vViewDir);
    }

    //Color-Sources
    float4 ColorAlpha= MatColorAlpha;
    float4 SpecularColorPower= MatSpecularColorPower;
    float4 EmissiveAmbient= MatEmissiveAmbient;
    float4 MirrorColorSaturation= MatMirrorColorSaturation;
    
    ColorAlpha*= TexColorAlpha.Sample(TextureSamplerWrap, In.vTextureCoord);
    
    Out.Color= float4(0, 0, 0, 1);
    Out.Color.rgb+= AmbientLight.rgb * EmissiveAmbient.a * ColorAlpha.rgb;
    Out.Color.rgb+= SpecularLight * SpecularColorPower.rgb;
    
    return(Out);
}