spieleprogrammierer.de - Forum und Wiki zur Spieleprogrammierung und Spieleentwicklung

C#-Quelltext

// Temp XieXie Test

import Console

// "Calculation" interface (or rather abstract class)
class Calc {
    
    String name()
    
    int apply(int lhs, int rhs)
    
}

// Test main class
class Test {
    
    // Folds all elements from 'list' and start with 'neutral'
    static int fold(int[] list, int neutral, Calc calc) {
        
        Console.write("method: ")
        Console.writeLine(calc.name())
        
        int s := neutral
        foreach x : list {
            s := calc.apply(s, x)
        }
        
        Console.write("elements: { ")
        
        for int i ; i < list.size() ; i++ {
            Console.write(list[i])
            if i < list.size() - 1 {
                Console.write(", ")
            } else {
                Console.writeLine(" }")
            }
        }
        
        Console.write("result = ")
        Console.writeLine(s)
        
        return s
    }
    
    // Prints the underline for the specified string
    static void underline(String s, int extent := 0) {
        for int i := -extent ; i < s.size() ; i++ {
            Console.write("-")
        }
        Console.writeLine("")
    }
    
    // Prints an headline for the specified string
    static void headline(String s) {
        Test.underline(s, 4)
        Console.write("| ")
        Console.write(s)
        Console.writeLine(" |")
        Test.underline(s, 4)
    }
    
    // Main entry point
    static void main() {
        
        Test.headline("folding test")
        
        var list := { 3, -12, 42, 8, 39 }
        
        Test.fold(
            list,
            0,
            new Calc() {
                String name() { return "sum" }
                int apply(int lhs, int rhs) {
                    return lhs + rhs
                }
            }
        )
        
        Test.fold(
            list,
            1,
            new Calc() {
                String name() { return "multiplication" }
                int apply(int lhs, int rhs) {
                    return lhs * rhs
                }
            }
        )
        
    }
    
}

Quellcode

----------------
| folding test |
----------------
method: sum
elements: { 3, -12, 42, 8, 39 }
result = 80
method: multiplication
elements: { 3, -12, 42, 8, 39 }
result = -471744

C#-Quelltext

// XieXie Nesting Test
// 08/06/2015

import Console

class Printer { void print() }

class Test {

    static void main() {
        
        /*
        Iterate over list, which is returned by "getArray",
        from an anonymous class, which is derived from "Object"
        */
        foreach x :
            new Object() {
                int[] getArray() {
                    return { 42, 3, -12 }
                }
            }.getArray()
        {
            Console.writeLine(x)
        }
        
        // Array access and anonymous class
        {
            null,
            new Printer() {
                void print() {
                    Console.writeLine("\(__CLASS__).\(__PROC__)")
                }
            },
            null
        }[1].print()
        
        // Call procedure with array, immediately after object instantiation
        Console.writeLine(
            new Object() {
                int sum(int[] list) {
                    int s
                    foreach x : list {
                        s += x
                    }
                    return s
                }
            }.sum({ 1, 2, 3 })
        )
        
    }
    
}